paprefs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   3 # Contributor: William Rea <sillywilly@gmail.com>
   4 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   5
   6 pkgname=paprefs
   7 pkgver=1.2
   8 pkgrel=1
   9 pkgdesc="Configuration dialog for PulseAudio"
  10 url="https://freedesktop.org/software/pulseaudio/paprefs/"
  11 license=(GPL2)
  12 arch=(x86_64)
  13 depends=(gtkmm3 libsigc++ 'pulseaudio>=12.0')
  14 makedepends=(meson lynx tidy git)
  15 conflicts=(pipewire-pulse)
  16 _commit=d70f061e1703c53aa327d3e836222e47dde86204  # tags/v1.2^0
  17 source=("git+https://gitlab.freedesktop.org/pulseaudio/paprefs.git#commit=$_commit")
  18 sha512sums=('SKIP')
  19
  20 pkgver() {
  21   cd paprefs
  22   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd paprefs
  27 }
  28
  29 build() {
  30   arch-meson paprefs build -D lynx=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40   install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 build/doc/README
  41 }