stoken/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Stephen Brown II <Stephen [dot] Brown2 [at] gmail.com>
   3
   4 pkgname=stoken
   5 pkgver=0.92
   6 pkgrel=4
   7 pkgdesc='RSA SecurID-compatible software token for Linux/UNIX systems'
   8 url='https://github.com/cernekee/stoken'
   9 arch=('x86_64')
  10 license=('LGPL2.1')
  11 depends=('nettle' 'libxml2')
  12 makedepends=('gtk3')
  13 optdepends=('gtk3: required for stoken-gui')
  14 provides=('libstoken.so')
  15 source=(https://downloads.sourceforge.net/stoken/${pkgname}-${pkgver}.tar.gz{,.asc})
  16 sha256sums=('aa2b481b058e4caf068f7e747a2dcf5772bcbf278a4f89bc9efcbf82bcc9ef5a'
  17             'SKIP')
  18 validpgpkeys=('45DFF2D5205FE8CD74C2EE6C63B81599BC0B0D65')
  19
  20 prepare() {
  21   cd ${pkgname}-${pkgver}
  22   autoreconf -fiv
  23 }
  24
  25 build() {
  26   cd ${pkgname}-${pkgver}
  27   ./configure --prefix=/usr
  28   make
  29 }
  30
  31 check() {
  32   cd ${pkgname}-${pkgver}
  33   make -k check
  34 }
  35
  36 package() {
  37   cd ${pkgname}-${pkgver}
  38   make DESTDIR="${pkgdir}" install
  39   install -Dm 644 CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
  40 }
  41
  42 # vim: ts=2 sw=2 et: