telepathy-farstream/repos/extra-x86_64/PKGBUILD

   1 # Contributor: Ionut Biru <ibiru@archlinux.org>
   2
   3 pkgname=telepathy-farstream
   4 pkgver=0.6.2
   5 pkgrel=7
   6 pkgdesc="Telepathy GLib-based client library that uses Farstream to handle Call channels"
   7 arch=(x86_64)
   8 url="https://telepathy.freedesktop.org/components/telepathy-farstream/"
   9 license=(LGPL2.1)
  10 depends=(telepathy-glib farstream)
  11 makedepends=(dbus-glib gobject-introspection gtk-doc git glib2-docs)
  12 replaces=(telepathy-farsight)
  13 _commit=0b1bba79cfe94e7676fe69e9e0d2e3983a3c14c5  # tags/telepathy-farstream-0.6.2^0
  14 source=("git+https://github.com/TelepathyIM/telepathy-farstream#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^telepathy-farstream-//;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd "$pkgname"
  29   ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/telepathy \
  30     --disable-static --enable-gtk-doc
  31   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  32   make
  33 }
  34
  35 package() {
  36   cd "$pkgname"
  37   make DESTDIR="$pkgdir" install
  38 }
  39
  40 # vim:set ts=2 sw=2 et: