usbutils/repos/core-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Tom Gundersen <teg@jklm.no>
   4 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   5 # Contributor: Curtis Campbell <curtisjamescampbell@hotmail.com>
   6
   7 pkgname=usbutils
   8 pkgver=015
   9 pkgrel=2
  10 pkgdesc="A collection of USB tools to query connected USB devices"
  11 arch=(x86_64)
  12 url="https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
  13 license=(GPL2 GPL3)
  14 depends=(glibc hwdata)
  15 makedepends=(libusb systemd)
  16 optdepends=(
  17   'python: for lsusb.py usage'
  18   'coreutils: for lsusb.py usage'
  19 )
  20 source=(https://www.kernel.org/pub/linux/utils/usb/usbutils/$pkgname-$pkgver.tar{.xz,.sign})
  21 sha512sums=('cda0070138400703d7429d39dee49130aedaa704292531e6af57b347cc62422ca609540650926e74335f71d67d7d4655418be4824e1eb8a2b065c7b395feaa87'
  22             'SKIP')
  23 b2sums=('1074c7159e9e6729f03f98e1f38fa0b3fef3e744b5297e6d97a5fc44ea374e2d5a0c481e14b2a034bca201048b1305c3877dbb15e3c4c04b228b4036048d8904'
  24         'SKIP')
  25 validpgpkeys=('647F28654894E3BD457199BE38DBBDC86092693E')  # Greg Kroah-Hartman <gregkh@linuxfoundation.org>
  26
  27 prepare() {
  28   cd $pkgname-$pkgver
  29   autoreconf -fiv
  30 }
  31
  32 build() {
  33   cd $pkgname-$pkgver
  34   ./configure \
  35     --prefix=/usr \
  36     --datadir=/usr/share/hwdata
  37   make
  38 }
  39
  40 package() {
  41   depends+=(
  42     libusb libusb-1.0.so
  43     systemd-libs libudev.so
  44   )
  45
  46   cd $pkgname-$pkgver
  47   make DESTDIR="$pkgdir" install
  48   install -vDm 644 NEWS -t "$pkgdir/usr/share/doc/$pkgname/"
  49 }