xfce4-systemload-plugin/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3 # Contributor: Aurelien Foret <orelien@chez.com>
   4
   5 pkgname=xfce4-systemload-plugin
   6 pkgver=1.3.2
   7 pkgrel=1
   8 pkgdesc="System load plugin for the Xfce panel"
   9 arch=('x86_64')
  10 license=('custom')
  11 url="https://docs.xfce.org/panel-plugins/xfce4-systemload-plugin"
  12 groups=('xfce4-goodies')
  13 depends=('xfce4-panel' 'libgtop')
  14 makedepends=('intltool')
  15 source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  16 sha256sums=('bb303fc3020e053ad1fa0b8fcbf0d7681c5563bb8f649357d6a95a577802b072')
  17
  18 build() {
  19   cd $pkgname-$pkgver
  20
  21   ./configure \
  22     --prefix=/usr \
  23     --sysconfdir=/etc \
  24     --localstatedir=/var \
  25     --disable-static
  26   make
  27 }
  28
  29 package() {
  30   cd $pkgname-$pkgver
  31   make DESTDIR="$pkgdir" install
  32   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  33 }
  34
  35 # vim:set ts=2 sw=2 et: