archlinux-keyring/trunk/PKGBUILD

   1 # Maintainer: Pierre Schmitz <pierre@archlinux.de>
   2 # Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3
   4 pkgname=archlinux-keyring
   5 _tag='7f697db5df3ed30142fc181f24ba6165039a693b' # git rev-parse ${pkgver}
   6 pkgver=20230130
   7 pkgrel=1
   8 pkgdesc='Arch Linux PGP keyring'
   9 arch=('any')
  10 url='https://gitlab.archlinux.org/archlinux/archlinux-keyring/'
  11 license=('GPL3')
  12 install=$pkgname.install
  13 depends=('pacman')
  14 makedepends=('git' 'python' 'sequoia-sq' 'pkgconf' 'systemd')
  15 checkdepends=('python-coverage' 'python-pytest')
  16 source=("archlinux-keyring::git+https://gitlab.archlinux.org/archlinux/archlinux-keyring.git#tag=${_tag}?signed")
  17 sha256sums=('SKIP')
  18 validpgpkeys=('02FD1C7A934E614545849F19A6234074498E9CEE'  # Christian Hesse <eworm@archlinux.org>
  19               'C7E7849466FE2358343588377258734B41C31549'  # David Runge <dvzrv@archlinux.org>
  20               '4AA4767BBC9C4B1D18AE28B77F2D434B9741E8AC'  # Pierre Schmitz <pierre@archlinux.org>
  21               'CFA6AF15E5C74149FC1D8C086D1655C14CE1C13E'  # Florian Pritz <bluewind@archlinux.org>
  22               'ECCAC84C1BA08A6CC8E63FBBF22FB1D78A77AEAB'  # Giancarlo Razzolini <grazzolini@archlinux.org>
  23               'E240B57E2C4630BA768E2F26FC1B547C8D8172C8'  # Levente Polyak <anthraxx@archlinux.org>
  24               'C100346676634E80C940FB9E9C02FF419FECBE16') # Morten Linderud <foxboron@archlinux.org>
  25
  26 build() {
  27   cd archlinux-keyring/
  28
  29   make build
  30 }
  31
  32 check() {
  33   cd archlinux-keyring/
  34
  35   make check
  36 }
  37
  38 package() {
  39   cd archlinux-keyring/
  40
  41   make PREFIX='/usr' DESTDIR="${pkgdir}" install
  42 }