portmidi/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=portmidi
   5 pkgver=236
   6 pkgrel=1
   7 pkgdesc="Cross platform library for interfacing with OS MIDI I/O APIs"
   8 arch=('x86_64')
   9 url="https://github.com/mixxxdj/portmidi"
  10 license=('MIT')
  11 depends=('glibc')
  12 makedepends=('alsa-lib' 'cmake')
  13 provides=('libportmidi.so' 'libporttime.so')
  14 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/mixxxdj/portmidi/archive/refs/tags/${pkgver}.tar.gz")
  15 sha512sums=('901729440c4b8c654ab17c4c4f1e3986813bf1e4ad1a874f46e7b1ee0c9ef4ee9f1ecfdf71012fb56b055a6185194dd22c520ae87b9f2259c18af5d189ca57da')
  16 b2sums=('618c3778b8b2170a145ec956cd4721e731cc135d0192e4b1c35b2c93b6b0f0e74085d044beafe2095b3d8e02e1776f442ae174d342c3f391d04a2aab378b547a')
  17
  18 build() {
  19   cd "${pkgname}-${pkgver}"
  20   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  21         -DCMAKE_BUILD_TYPE='None' \
  22         -DBUILD_TESTING=ON \
  23         -Wno-dev \
  24         -B build \
  25         -S .
  26   make VERBOSE=1 -C build
  27 }
  28
  29 check() {
  30   cd "${pkgname}-${pkgver}"
  31   make VERBOSE=1 test -C build
  32 }
  33
  34 package() {
  35   depends+=('libasound.so')
  36
  37   cd "${pkgname}-${pkgver}"
  38   make DESTDIR="${pkgdir}" install -C build
  39   install -vDm 644 license.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40   install -vDm 644 {CHANGELOG,README}.txt \
  41     -t "${pkgdir}/usr/share/doc/${pkgname}"
  42 }