gnutls/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   3
   4 pkgname=gnutls
   5 pkgver=3.7.2
   6 pkgrel=2
   7 pkgdesc="A library which provides a secure layer over a reliable transport layer"
   8 arch=('x86_64')
   9 license=('GPL3' 'LGPL2.1')
  10 url="https://www.gnutls.org/"
  11 options=('!zipman')
  12 depends=('gcc-libs' 'libtasn1' 'readline' 'zlib' 'nettle' 'p11-kit' 'libidn2'
  13          'libidn2.so' 'libunistring')
  14 checkdepends=('net-tools')
  15 optdepends=('guile: for use with Guile bindings')
  16 source=(https://www.gnupg.org/ftp/gcrypt/gnutls/v3.7/${pkgname}-${pkgver}.tar.xz{,.sig})
  17 sha256sums=('646e6c5a9a185faa4cea796d378a1ba8e1148dbb197ca6605f95986a25af2752'
  18             'SKIP')
  19 validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # "Daiki Ueno <ueno@unixuser.org>"
  20
  21 build() {
  22   cd ${pkgname}-${pkgver}
  23   ./configure --prefix=/usr \
  24         --disable-static \
  25         --with-idn \
  26         --enable-openssl-compatibility \
  27         --enable-guile --with-guile-site-dir=no \
  28         --with-default-trust-store-pkcs11="pkcs11:"
  29   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  30   make
  31 }
  32
  33 check() {
  34   cd ${pkgname}-${pkgver}
  35   make check
  36 }
  37
  38 package() {
  39   cd ${pkgname}-${pkgver}
  40   make DESTDIR="${pkgdir}" install
  41
  42   # lots of .png files are put into infodir and are gzipped by makepkg! this needs to be fixed by using !zipman
  43   # gzip -9 all files in infodir and manpages manually
  44   find "$pkgdir/usr/share/info" -name '*.info*' -exec gzip -n -9 {} \;
  45   find "$pkgdir/usr/share/man" -exec gzip -n -9 {} \;
  46 }