ocaml-ctypes/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Armin K. <krejzi at email dot com>
   3
   4 pkgname=ocaml-ctypes
   5 pkgver=0.20.1
   6 pkgrel=1
   7 pkgdesc="Library for binding to C libraries using pure OCaml"
   8 arch=('x86_64')
   9 url="https://github.com/ocamllabs/ocaml-ctypes"
  10 license=('MIT')
  11 depends=('ocaml>=4.14.0' 'libffi' 'ocaml-integers' 'ocaml-bigarray-compat')
  12 makedepends=('ocaml-findlib' 'ocaml-compiler-libs')
  13 options=('!strip' '!makeflags')
  14 source=($pkgname-$pkgver.tar.gz::https://github.com/ocamllabs/ocaml-ctypes/archive/$pkgver.tar.gz)
  15 sha512sums=('f95e65ce5003a07634afcbee431cb23c54c8335f926074615fc8d76ab777b9d2fce8f75bb25bbb6ed9550a7d6237fb377aa9ad65a426d2d7e387f86c1158fe4a')
  16
  17 build() {
  18   cd "$srcdir/$pkgname-$pkgver"
  19   make
  20 }
  21
  22 package() {
  23   cd "$srcdir/$pkgname-$pkgver"
  24
  25   local _destdir="$pkgdir$(ocamlfind printconf destdir)"
  26   install -d "$_destdir/stublibs"
  27
  28   make OCAMLFIND_DESTDIR="$_destdir" install
  29
  30   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  31 }
  32
  33 # vim:set ts=2 sw=2 et: