fuse3/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Mark Rosenstand <mark@archlinux.org>
   4
   5 pkgbase=fuse3
   6 pkgname=(fuse-common fuse3)
   7 pkgver=3.10.5
   8 pkgrel=1
   9 arch=('x86_64')
  10 url='https://github.com/libfuse/libfuse'
  11 license=('GPL2')
  12 makedepends=('pkg-config' 'meson' 'udev')
  13 options=(!emptydirs)
  14 source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.xz{,.asc})
  15 sha256sums=('b2e283485d47404ac896dd0bb7f7ba81e1470838e677e45f659804c3a3b69666'
  16             'SKIP')
  17 validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>
  18
  19 build() {
  20   cd fuse-$pkgver
  21
  22   rm -rf build
  23   meson --prefix=/usr --sbindir=bin -D examples=false . build
  24   cd build
  25   ninja
  26 }
  27
  28 package_fuse-common() {
  29   pkgdesc="Common files for fuse2/3 packages"
  30   backup=(etc/fuse.conf)
  31
  32   install -Dm644 fuse-${pkgver}/util/fuse.conf "${pkgdir}"/etc/fuse.conf
  33 }
  34
  35 package_fuse3() {
  36   pkgdesc="A library that makes it possible to implement a filesystem in a userspace program."
  37   depends=('fuse-common' 'glibc')
  38
  39   cd fuse-$pkgver/build
  40
  41   DESTDIR="${pkgdir}" ninja install
  42
  43   rm -r "${pkgdir}"/etc/init.d
  44   rm -r "${pkgdir}"/etc/fuse.conf
  45
  46   # static device nodes are handled by udev
  47   rm -r "${pkgdir}"/dev
  48 }