gtk-doc/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gtk-doc
   5 pkgver=1.33.2
   6 pkgrel=1
   7 pkgdesc="Documentation tool for public library API"
   8 url="https://www.gtk.org/gtk-doc/"
   9 arch=(any)
  10 license=(GPL FDL)
  11 depends=(docbook-xsl docbook-xml glib2-docs python-lxml python-pygments
  12          python-anytree)
  13 makedepends=(dblatex git yelp-tools meson)
  14 checkdepends=(bc gtk3 python-six python-parameterized)
  15 optdepends=('dblatex: PDF support')
  16 _commit=14391142ee9d43da116f0f530746ae34cc46930a  # tags/1.33.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gtk-doc.git#commit=$_commit"
  18         0001-Partially-revert-a-gtk-doc-1.31-change-that-broke-e-.patch)
  19 sha256sums=('SKIP'
  20             '95208f0e0dd6e888892b04e3396b131218d1d98e433edfbd4af70b158921319c')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/GTK_DOC_//;s/_/\./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29
  30   # https://gitlab.gnome.org/GNOME/gtk-doc/-/merge_requests/58
  31   git apply -3 ../0001-Partially-revert-a-gtk-doc-1.31-change-that-broke-e-.patch
  32 }
  33
  34 build() {
  35   arch-meson $pkgname build
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package() {
  44   DESTDIR="$pkgdir" meson install -C build
  45   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  46   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  47 }