docbook-utils/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 # Contributor: Chris Severance aur.severach aATt spamgourmet dott com
   4 # Contributor: Andreas B. Wagner <AndreasBWagner@pointfree.net>
   5 # Contributor: Suat SARIALP <muhendis.suat@gmail.com>
   6
   7 pkgname=docbook-utils
   8 pkgver=0.6.14
   9 pkgrel=12
  10 pkgdesc='Shell scripts to manage DocBook documents'
  11 arch=('any')
  12 url="https://www.sourceware.org/docbook-tools/"
  13 license=('GPL2')
  14 depends=('openjade' 'docbook-dsssl' 'docbook-sgml31')
  15 makedepends=('perl-sgmls')
  16 optdepends=('perl-sgmls: for conversion to man and texinfo'
  17             'lynx: for conversion to txt'
  18             'texlive-htmlxml: for conversion to pdf')
  19 source=(https://sourceware.org/ftp/docbook-tools/new-trials/SOURCES/${pkgname}-${pkgver}.tar.gz
  20         #ftp://sources.redhat.com/pub/docbook-tools/new-trials/SOURCES/${pkgname}-${pkgver}.tar.gz
  21         db2html # script taken from Fedora
  22         docbook-utils-0.6.14-grep_fix-1.patch)
  23 sha256sums=('48faab8ee8a7605c9342fb7b906e0815e3cee84a489182af38e8f7c0df2e92e9'
  24             '10b9c29ad659cce5036871a6e85598fd33cc52c0c38cf059eeb485382a5d90d7'
  25             'ddf0ddca0a540fd4f34f38b7b9090f96746e37da12b4e2bf8f4174c5ad61f54a')
  26
  27 prepare() {
  28   cd "${pkgname}-${pkgver}"
  29   patch -Np1 -i "${srcdir}"/docbook-utils-0.6.14-grep_fix-1.patch
  30 }
  31
  32 build() {
  33   cd "${pkgname}-${pkgver}"
  34   ./configure --prefix=/usr \
  35     --sysconfdir=/etc \
  36     --mandir=/usr/share/man
  37   make
  38 }
  39
  40 package() {
  41   cd "${pkgname}-${pkgver}"
  42   make install DESTDIR="${pkgdir}" htmldir="/usr/share/doc/${pkgname}/html"
  43
  44   #common alternative names
  45   for doctype in 'html' 'ps' 'dvi' 'man' 'pdf' 'rtf' 'tex' 'texi' 'txt'; do
  46     ln -sv "docbook2${doctype}" "${pkgdir}/usr/bin/db2${doctype}"
  47     ln -sv "jw.1" "${pkgdir}/usr/share/man/man1/db2${doctype}"
  48   done
  49
  50   # db2html is not just a symlink, as it has to create the output directory - FS#67758
  51   rm "${pkgdir}/usr/bin/db2html"
  52   install -p -m 755 ../db2html "${pkgdir}/usr/bin/db2html"
  53 }