gedit/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gedit
   5 pkgver=42.2
   6 pkgrel=1
   7 pkgdesc="GNOME Text Editor"
   8 url="https://wiki.gnome.org/Apps/Gedit"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(gtksourceview4 gsettings-desktop-schemas libpeas gspell python-gobject)
  12 makedepends=(yelp-tools vala gobject-introspection git gtk-doc meson
  13              appstream-glib desktop-file-utils libxml2)
  14 optdepends=('gedit-plugins: Additional features')
  15 conflicts=('gedit-code-assistance<=3.16.0+4+gd19b879-1')
  16 groups=(gnome)
  17 options=(debug)
  18 _commit=7de455c111ad507385451aa23747f95ca75b18cb  # tags/42.2^0
  19 source=("git+https://gitlab.gnome.org/GNOME/gedit.git#commit=$_commit"
  20         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  21 sha256sums=('SKIP'
  22             'SKIP')
  23
  24 pkgver() {
  25   cd gedit
  26   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd gedit
  31
  32   git submodule init
  33   git submodule set-url subprojects/libgd "$srcdir/libgd"
  34   git submodule update
  35 }
  36
  37 build() {
  38   arch-meson gedit build \
  39     -D gtk_doc=true \
  40     -D require_all_tests=true
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50 }