libevdev/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 pkgname=libevdev
   4 pkgver=1.13.0
   5 pkgrel=1
   6 pkgdesc="Wrapper library for evdev devices"
   7 arch=(x86_64)
   8 url="https://www.freedesktop.org/wiki/Software/libevdev/"
   9 license=(custom:MIT)
  10 depends=('glibc')
  11 makedepends=('python' 'check' 'valgrind' 'doxygen' 'meson')
  12 provides=('libevdev.so')
  13 options=('debug')
  14 source=(https://freedesktop.org/software/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
  15 sha512sums=('f30f14c44ef4d4829625aa4c28f10555f333905486f9d39c18cd3ca35e87128a0c24c1bc18ca37b6bf98bc8f7fad27e1bc68678a58e6e6fff3b8d99502ac6905'
  16             'SKIP')
  17 validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
  18
  19 build() {
  20   arch-meson $pkgname-$pkgver build \
  21     -D documentation=disabled
  22   meson compile -C build
  23 }
  24 check() {
  25   meson test -C build
  26 }
  27
  28 package() {
  29   DESTDIR="$pkgdir" meson install -C build
  30
  31   install -Dm644 $pkgname-$pkgver/COPYING \
  32     "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  33 }