libgit2-glib/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: David Runge <dvzrv@archlinux.org>
   4
   5 pkgname=libgit2-glib
   6 pkgver=1.0.0.1
   7 pkgrel=2
   8 pkgdesc="GLib wrapper for libgit2"
   9 url="https://wiki.gnome.org/Projects/Libgit2-glib"
  10 license=('LGPL2.1')
  11 arch=('x86_64')
  12 depends=('glibc')
  13 makedepends=('gobject-introspection' 'glib2' 'libgit2' 'gtk-doc' 'meson'
  14              'python-gobject' 'vala' 'git')
  15 _commit=391b764ac7e2915ed564f5e144cfdb1ae51fbc4e  # tags/v1.0.0.1^0
  16 source=("git+https://gitlab.gnome.org/GNOME/libgit2-glib.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build -D gtk_doc=true
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   depends+=('libgio-2.0.so' 'libgit2.so' 'libglib-2.0.so' 'libgobject-2.0.so')
  39   provides+=('libgit2-glib-1.0.so')
  40
  41   meson install -C build --destdir "$pkgdir"
  42
  43   # strip $pkgdir from embedded paths:
  44   python -m compileall -d "/usr/lib" "$pkgdir/usr/lib"
  45   python -O -m compileall -d "/usr/lib" "$pkgdir/usr/lib"
  46
  47   install -vDm 644 $pkgname/{AUTHORS,ChangeLog,NEWS,README} \
  48     -t "${pkgdir}/usr/share/doc/${pkgname}"
  49 }