libical/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Pierre Schmitz <pierre@archlinux.de>
   4
   5 pkgname=libical
   6 pkgver=3.0.14
   7 pkgrel=3
   8 pkgdesc="An open source reference implementation of the icalendar data type and serialization format"
   9 arch=('x86_64')
  10 url='https://github.com/libical/libical'
  11 license=('LGPL' 'MPL')
  12 depends=('glibc' 'glib2' 'icu' 'db' 'libxml2')
  13 makedepends=('cmake' 'ninja' 'gtk-doc' 'doxygen' 'vala' 'gobject-introspection')
  14 checkdepends=('python-gobject')
  15 options=('debug')
  16 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz")
  17 sha512sums=('36da5516672976c71b049a12af36164d91f9b655f81f1884766558149f25e80c30e64d15da848842f8a629295d708f39ce6fa63a3b0da39b5cbeb91911a4e6d8')
  18
  19 build() {
  20   cmake -S "${pkgname}-${pkgver}" -B build -G Ninja \
  21     -DCMAKE_BUILD_TYPE=None \
  22     -DCMAKE_INSTALL_PREFIX=/usr \
  23     -DCMAKE_INSTALL_LIBEXECDIR=lib \
  24     -DGOBJECT_INTROSPECTION=true \
  25     -DICAL_GLIB_VAPI=true \
  26     -DSHARED_ONLY=true
  27   cmake --build build
  28 }
  29
  30 check() {
  31   cmake --build build --target test
  32 }
  33
  34 package() {
  35   DESTDIR="${pkgdir}" cmake --install build
  36 }