libytnef/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Andre Klitzing <aklitzing () online () de>
   4
   5 pkgname=libytnef
   6 pkgver=2.0
   7 pkgrel=2
   8 epoch=1
   9 pkgdesc="Yerase's TNEF Stream Reader library (decodes winmail.dat)"
  10 url="https://github.com/Yeraze/ytnef"
  11 license=(GPL)
  12 arch=(x86_64)
  13 depends=(glibc)
  14 makedepends=(perl git)
  15 optdepends=('perl: ytnefprocess')
  16 provides=(libytnef.so)
  17 _commit=f80f624d373997afa3e3bfc074948b26d171d210  # tags/v2.0
  18 source=("git+https://github.com/Yeraze/ytnef#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd ytnef
  23   git describe --tags | sed 's/^v//;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd ytnef
  28   ./autogen.sh
  29 }
  30
  31 build() {
  32   cd ytnef
  33   ./configure --prefix=/usr --disable-static
  34   make
  35 }
  36
  37 package() {
  38   cd ytnef
  39   make DESTDIR="$pkgdir" install
  40 }