mkinitcpio/repos/core-any/PKGBUILD

   1 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   2 # Maintainer: Dave Reisner <dreisner@archlinux.org>
   3 # Maintainer: Thomas Bächler <thomas@archlinux.org>
   4
   5 pkgname=mkinitcpio
   6 pkgver=31
   7 pkgrel=3
   8 pkgdesc="Modular initramfs image creation utility"
   9 arch=('any')
  10 url='https://github.com/archlinux/mkinitcpio'
  11 license=('GPL')
  12 depends=('awk' 'mkinitcpio-busybox>=1.19.4-2' 'kmod' 'util-linux>=2.23' 'libarchive' 'coreutils'
  13          'bash' 'binutils' 'diffutils' 'findutils' 'grep' 'filesystem>=2011.10-1' 'zstd' 'systemd')
  14 optdepends=('gzip: Use gzip compression for the initramfs image'
  15             'xz: Use lzma or xz compression for the initramfs image'
  16             'bzip2: Use bzip2 compression for the initramfs image'
  17             'lzop: Use lzo compression for the initramfs image'
  18             'lz4: Use lz4 compression for the initramfs image'
  19             'mkinitcpio-nfs-utils: Support for root filesystem on NFS')
  20 provides=('initramfs')
  21 backup=('etc/mkinitcpio.conf')
  22 source=("https://sources.archlinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig}
  23        0001-Fix-the-warning-about-missing-modules.builtin.modinf.patch)
  24 install=mkinitcpio.install
  25 sha512sums=('4ef87c2e4f579b292c38f9c487e78b3b99f6db77909cab322e860e5ca70aca3747fcfc272e2e15c9a3605c924ab178057b8b23151f98debc5d96e65f3c0c49d5'
  26             'SKIP'
  27             'fd348d6fcff249672b495db50fa67ce06d5d9a0c8f749c8b488bc1e4b43c9b850a5ad87392230fbe8b715422bb14e760bb0ad219cfcf1d7e132c6a7e4dd118a6')
  28 b2sums=('0113e288906e3b5fa485c29c00e7df60d85addd96718c45531031a686f18c739fa18303b6cac374d35b85edb7b663e221c8dc9158dff08c75858a4ed4dd154bf'
  29         'SKIP'
  30         '5a05cee0382284d6cc0a2033e872b7c4c9f01ddfe6d3550974b5eab9a8a18690d1115b57d8d08153497fed08fd55b69f8b4a4cbcbe67795d615cc06ea7c86618')
  31 validpgpkeys=('ECCAC84C1BA08A6CC8E63FBBF22FB1D78A77AEAB')    # Giancarlo Razzolini
  32
  33 prepare() {
  34   cd $pkgname-$pkgver
  35   patch -Np1 < "$srcdir"/0001-Fix-the-warning-about-missing-modules.builtin.modinf.patch
  36
  37 }
  38
  39 check() {
  40   make -C "$pkgname-$pkgver" check
  41 }
  42
  43 package() {
  44   make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install
  45 }