sushi/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=sushi
   5 pkgver=42.0
   6 pkgrel=1
   7 pkgdesc="A quick previewer for Nautilus"
   8 url="https://gitlab.gnome.org/GNOME/sushi"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 groups=(gnome)
  12 depends=(gtk3 gjs webkit2gtk-4.1 gtksourceview4 evince gst-plugins-base-libs
  13          gst-plugin-gtk)
  14 makedepends=(gobject-introspection git meson)
  15 optdepends=('unoconv: OpenDocument formats')
  16 options=(debug)
  17 _commit=8f0191433175a90272e8e1f9a6518e7520be8470  # tags/42.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/sushi.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd sushi
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd sushi
  28 }
  29
  30 build() {
  31   arch-meson sushi build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 et: