util-linux/trunk/PKGBUILD

   1 # Maintainer: Tom Gundersen <teg@jklm.no>
   2 # Maintainer: Dave Reisner <dreisner@archlinux.org>
   3 # Contributor: judd <jvinet@zeroflux.org>
   4
   5 pkgbase=util-linux
   6 pkgname=(util-linux util-linux-libs)
   7 _pkgmajor=2.38
   8 _realver=${_pkgmajor}.1
   9 pkgver=${_realver/-/}
  10 pkgrel=1
  11 pkgdesc='Miscellaneous system utilities for Linux'
  12 url='https://github.com/karelzak/util-linux'
  13 arch=('x86_64')
  14 makedepends=('asciidoctor' 'libcap-ng' 'libxcrypt' 'python' 'systemd')
  15 license=('GPL2')
  16 options=('debug' 'strip')
  17 validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284')  # Karel Zak
  18 source=("https://www.kernel.org/pub/linux/utils/util-linux/v${_pkgmajor}/${pkgbase}-${_realver}.tar."{xz,sign}
  19         pam-{login,common,runuser,su}
  20         'util-linux.sysusers'
  21         '60-rfkill.rules'
  22         'rfkill-unblock_.service'
  23         'rfkill-block_.service')
  24 sha256sums=('60492a19b44e6cf9a3ddff68325b333b8b52b6c59ce3ebd6a0ecaa4c5117e84f'
  25             'SKIP'
  26             '99cd77f21ee44a0c5e57b0f3670f711a00496f198fc5704d7e44f5d817c81a0f'
  27             '57e057758944f4557762c6def939410c04ca5803cbdd2bfa2153ce47ffe7a4af'
  28             '48d6fba767631e3dd3620cf02a71a74c5d65a525d4c4ce4b5a0b7d9f41ebfea1'
  29             '3f54249ac2db44945d6d12ec728dcd0d69af0735787a8b078eacd2c67e38155b'
  30             '10b0505351263a099163c0d928132706e501dd0a008dac2835b052167b14abe3'
  31             '7423aaaa09fee7f47baa83df9ea6fef525ff9aec395c8cbd9fe848ceb2643f37'
  32             '8ccec10a22523f6b9d55e0d6cbf91905a39881446710aa083e935e8073323376'
  33             'a22e0a037e702170c7d88460cc9c9c2ab1d3e5c54a6985cd4a164ea7beff1b36')
  34
  35 build() {
  36   cd "${pkgbase}-${_realver}"
  37
  38   ./configure \
  39     --prefix=/usr \
  40     --libdir=/usr/lib \
  41     --bindir=/usr/bin \
  42     --sbindir=/usr/bin \
  43     --localstatedir=/var \
  44     --enable-usrdir-path \
  45     --enable-fs-paths-default=/usr/bin:/usr/local/bin \
  46     --enable-vipw \
  47     --enable-newgrp \
  48     --enable-chfn-chsh \
  49     --enable-write \
  50     --enable-mesg \
  51     --with-python=3
  52
  53   make
  54 }
  55
  56 package_util-linux() {
  57   conflicts=('rfkill' 'hardlink')
  58   provides=('rfkill' 'hardlink')
  59   replaces=('rfkill' 'hardlink')
  60   depends=('pam' 'shadow' 'coreutils' 'systemd-libs' 'libsystemd.so'
  61            'libudev.so' 'libcap-ng' 'libxcrypt' 'libcrypt.so' 'util-linux-libs'
  62            'libmagic.so' 'libncursesw.so')
  63   optdepends=('python: python bindings to libmount'
  64               'words: default dictionary for look')
  65   backup=(etc/pam.d/chfn
  66           etc/pam.d/chsh
  67           etc/pam.d/login
  68           etc/pam.d/runuser
  69           etc/pam.d/runuser-l
  70           etc/pam.d/su
  71           etc/pam.d/su-l)
  72
  73   cd "${pkgbase}-${_realver}"
  74
  75   make DESTDIR="${pkgdir}" usrsbin_execdir=/usr/bin install
  76
  77   # setuid chfn and chsh
  78   chmod 4755 "${pkgdir}"/usr/bin/{newgrp,ch{sh,fn}}
  79
  80   # install PAM files for login-utils
  81   install -Dm0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chfn"
  82   install -m0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chsh"
  83   install -m0644 "${srcdir}/pam-login" "${pkgdir}/etc/pam.d/login"
  84   install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser"
  85   install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser-l"
  86   install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su"
  87   install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su-l"
  88
  89   # TODO(dreisner): offer this upstream?
  90   sed -i '/ListenStream/ aRuntimeDirectory=uuidd' "${pkgdir}/usr/lib/systemd/system/uuidd.socket"
  91
  92   ### runtime libs are shipped as part of util-linux-libs
  93   rm "${pkgdir}"/usr/lib/lib*.{a,so}*
  94
  95   ### install systemd-sysusers
  96   install -Dm0644 "${srcdir}/util-linux.sysusers" \
  97     "${pkgdir}/usr/lib/sysusers.d/util-linux.conf"
  98
  99   install -Dm0644 "${srcdir}/60-rfkill.rules" \
 100     "${pkgdir}/usr/lib/udev/rules.d/60-rfkill.rules"
 101
 102   install -Dm0644 "${srcdir}/rfkill-unblock_.service" \
 103     "${pkgdir}/usr/lib/systemd/system/rfkill-unblock@.service"
 104   install -Dm0644 "${srcdir}/rfkill-block_.service" \
 105     "${pkgdir}/usr/lib/systemd/system/rfkill-block@.service"
 106 }
 107
 108 package_util-linux-libs() {
 109   pkgdesc="util-linux runtime libraries"
 110   provides=('libutil-linux' 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so' 'libuuid.so')
 111   conflicts=('libutil-linux')
 112   replaces=('libutil-linux')
 113
 114   make -C "${pkgbase}-${_realver}" DESTDIR="${pkgdir}" install-usrlib_execLTLIBRARIES
 115 }