gst-libav/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gst-libav
   5 pkgver=1.18.5
   6 pkgrel=1
   7 pkgdesc="Multimedia graph framework - libav plugin"
   8 url="https://gstreamer.freedesktop.org/"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(gst-plugins-base-libs bzip2 ffmpeg)
  12 makedepends=(python git meson)
  13 provides=("gst-ffmpeg=$pkgver-$pkgrel")
  14 _commit=9db917cab4c20e72e53ed962406a0d94636a2a39  # tags/1.18.5^0
  15 source=("git+https://gitlab.freedesktop.org/gstreamer/gst-libav.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build \
  29     -D doc=disabled \
  30     -D package-name="GStreamer FFmpeg Plugin (Arch Linux)" \
  31     -D package-origin="https://www.archlinux.org/"
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }