folks/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=folks
   5 pkgver=0.15.5
   6 pkgrel=1
   7 pkgdesc="Library to aggregates people into metacontacts"
   8 arch=(x86_64)
   9 url="https://wiki.gnome.org/Projects/Folks"
  10 license=(LGPL)
  11 depends=(libgee libxml2 evolution-data-server)
  12 makedepends=(gobject-introspection gtk-doc vala git meson python-dbusmock)
  13 provides=(libfolks.so libfolks-{dummy,eds}.so)
  14 options=(!lto debug)
  15 _commit=c75c2a55f171ec778a78d3d510add6993b353487  # tags/0.15.5^0
  16 source=("git+https://gitlab.gnome.org/GNOME/folks.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd folks
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd folks
  26 }
  27
  28 build() {
  29   local meson_options=(
  30     -D b_lto=false  # LTO copies some GType constructors
  31     -D docs=true
  32     -D telepathy_backend=false
  33   )
  34
  35   arch-meson folks build "${meson_options[@]}"
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs -t 4
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45 }
  46
  47 # vim:set sw=2 et: