libevdev/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 pkgname=libevdev
   4 pkgver=1.12.0
   5 pkgrel=1
   6 pkgdesc="Wrapper library for evdev devices"
   7 arch=(x86_64)
   8 url="https://www.freedesktop.org/wiki/Software/libevdev/"
   9 license=(custom:MIT)
  10 depends=('glibc')
  11 makedepends=('python' 'check' 'valgrind' 'doxygen' 'meson')
  12 provides=('libevdev.so')
  13 source=(https://freedesktop.org/software/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
  14 sha512sums=('6c1c1362d5112cdf3816d1f735c27e625f5463ebf10a83d675cd9364c3fb291ebcb91c051da442f1a36ed28ba7dd99af74546707f61274f7d5715c544a0ed04c'
  15             'SKIP')
  16 validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
  17
  18 build() {
  19   arch-meson $pkgname-$pkgver build \
  20     -D documentation=disabled
  21   meson compile -C build
  22 }
  23 check() {
  24   meson test -C build
  25 }
  26
  27 package() {
  28   DESTDIR="$pkgdir" meson install -C build
  29
  30   install -Dm644 $pkgname-$pkgver/COPYING \
  31     "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  32 }