xfce4-session/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: tobias <tobias funnychar archlinux.org>
   3
   4 pkgname=xfce4-session
   5 pkgver=4.16.0
   6 pkgrel=2
   7 pkgdesc="Session manager for Xfce"
   8 arch=('x86_64')
   9 url="https://docs.xfce.org/xfce/xfce4-session/start"
  10 license=('GPL2')
  11 groups=('xfce4')
  12 depends=('libxfce4ui' 'libwnck3' 'xfconf' 'libsm' 'polkit' 'xorg-iceauth'
  13          'xorg-xinit' 'xorg-xrdb' 'polkit-gnome' 'hicolor-icon-theme')
  14 makedepends=('intltool')
  15 optdepends=('gnome-keyring: for keyring support when GNOME compatibility is enabled'
  16             'xfce4-screensaver: for locking screen with xflock4'
  17             'xscreensaver: for locking screen with xflock4'
  18             'gnome-screensaver: for locking screen with xflock4'
  19             'xlockmore: for locking screen with xflock4'
  20             'slock: for locking screen with xflock4')
  21 source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2
  22         source-system-xinitrc-scripts.patch
  23         xfce-polkit-gnome-authentication-agent-1.desktop)
  24 sha256sums=('22f273f212481d71e0b5618c62710cd85f69aea74f5ea5c0093f7918b07d17b7'
  25             '6f14d529e4c4f30cd547110bd444cee8dc70c90511a397de18acb6c1fd63ea3e'
  26             '74c94c5f7893d714e04ec7d8b8520c978a5748757a0cdcf5128492f09f31b643')
  27
  28 prepare() {
  29   cd "$srcdir/$pkgname-$pkgver"
  30
  31   # https://bugzilla.xfce.org/show_bug.cgi?id=15440
  32   patch -Np1 -i ../source-system-xinitrc-scripts.patch
  33 }
  34
  35 build() {
  36   cd "$srcdir/$pkgname-$pkgver"
  37
  38   ./configure \
  39     --prefix=/usr \
  40     --sysconfdir=/etc \
  41     --libexecdir=/usr/lib/xfce4 \
  42     --localstatedir=/var \
  43     --disable-static \
  44     --disable-debug
  45   make
  46 }
  47
  48 package() {
  49   cd "$srcdir/$pkgname-$pkgver"
  50   make DESTDIR="$pkgdir" install
  51
  52   # Provide a default PolicyKit Authentication Agent (FS#42569)
  53   install -d "$pkgdir/etc/xdg/autostart"
  54   cp "$srcdir/xfce-polkit-gnome-authentication-agent-1.desktop" \
  55     "$pkgdir/etc/xdg/autostart/"
  56 }
  57
  58 # vim:set ts=2 sw=2 et: