opencolorio/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Dumitru Ursu <dima@ceata.org>
   3
   4 pkgname=opencolorio
   5 pkgver=2.1.1
   6 pkgrel=2
   7 pkgdesc="A color management framework for visual effects and animation"
   8 arch=('x86_64')
   9 url="https://opencolorio.org"
  10 license=('BSD')
  11 depends=('freeglut' 'glew' 'lcms2' 'tinyxml' 'yaml-cpp' 'imath' 'pystring')
  12 makedepends=('cmake' 'python' 'pybind11' 'ninja')
  13 optdepends=('python: python bindings')
  14 source=($pkgname-$pkgver.tar.gz::https://github.com/AcademySoftwareFoundation/OpenColorIO/archive/v$pkgver.tar.gz)
  15 sha512sums=('86585ec860d460b158f24efb82f202deced7ce96a6bfefd42f39cad9c112add68cca6935f383f5d718c07fe1c121d8ed8b0d2069321f1dafb8ce68b49bc75194')
  16
  17 build() {
  18   cd OpenColorIO-$pkgver
  19
  20   CXXFLAGS+=" -ffat-lto-objects"
  21   cmake \
  22     -GNinja \
  23     -Bbuild \
  24     -DCMAKE_INSTALL_PREFIX=/usr \
  25     -DCMAKE_INSTALL_LIBDIR=lib
  26   ninja -C build
  27 }
  28
  29 package() {
  30   cd OpenColorIO-$pkgver
  31
  32   DESTDIR="$pkgdir" ninja -C build install
  33   install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
  34 }
  35
  36 # vim:set ts=2 sw=2 et: