qt6-quick3d/kde-unstable/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=qt6-quick3d
   6 _qtver=6.3.0-beta2
   7 pkgver=${_qtver/-/}
   8 pkgrel=1
   9 arch=(x86_64)
  10 url='https://www.qt.io'
  11 license=(GPL3)
  12 pkgdesc='Qt module and API for defining 3D content in Qt Quick'
  13 depends=(qt6-quicktimeline)
  14 makedepends=(cmake ninja qt6-shadertools assimp)
  15 optdepends=('qt6-shadertools: for shadergen' 'assimp: assimp import plugin')
  16 groups=(qt6)
  17 options=(debug)
  18 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  19 source=(https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  20 sha256sums=('9c7511fff6177c3b36d29f74f64401ba95c0e2b6f8a7b84b767473937bf5e47e')
  21
  22 build() {
  23   cmake -B build -S $_pkgfn -G Ninja
  24   cmake --build build
  25 }
  26
  27 package() {
  28   DESTDIR="$pkgdir" cmake --install build
  29
  30   install -d "$pkgdir"/usr/share/licenses
  31   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  32 }