vala/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4 # Contributor: Timm Preetz <timm@preetz.us>
   5
   6 pkgname=vala
   7 pkgver=0.56.5
   8 pkgrel=1
   9 pkgdesc='Compiler for the GObject type system'
  10 url='https://wiki.gnome.org/Projects/Vala'
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(
  14   gcc
  15   glib2
  16   graphviz
  17   gtk-doc
  18   pkg-config
  19   ttf-font
  20 )
  21 makedepends=(
  22   autoconf-archive
  23   git
  24   help2man
  25   libxslt
  26   vala
  27 )
  28 checkdepends=(
  29   dbus
  30   gobject-introspection
  31   libx11
  32 )
  33 provides=(
  34   libvala-${pkgver%.*}.so
  35   libvaladoc-${pkgver%.*}.so
  36   valadoc
  37 )
  38 conflicts=(valadoc)
  39 replaces=(valadoc)
  40 _commit=9c8ee8f065e572ed9feecdf118145d5b1748fada  # tags/0.56.5^0
  41 source=("git+https://gitlab.gnome.org/GNOME/vala.git#commit=$_commit")
  42 b2sums=('SKIP')
  43
  44 pkgver() {
  45   cd vala
  46   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  47 }
  48
  49 prepare() {
  50   cd vala
  51   NOCONFIGURE=1 ./autogen.sh
  52 }
  53
  54 build() {
  55   cd vala
  56   ./configure --prefix=/usr
  57   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  58   make
  59 }
  60
  61 check() {
  62   cd vala
  63   make check
  64 }
  65
  66 package() {
  67   cd vala
  68   make DESTDIR="$pkgdir" install
  69 }
  70
  71 # vim:set sw=2 sts=-1 et: