rhythmbox/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4
   5 pkgname=rhythmbox
   6 pkgver=3.4.6
   7 pkgrel=1
   8 pkgdesc="Music playback and management application"
   9 arch=(x86_64)
  10 license=(GPL)
  11 url="https://wiki.gnome.org/Apps/Rhythmbox"
  12 depends=(dconf gst-plugins-base gst-plugins-good libsoup json-glib libnotify
  13          libpeas media-player-info totem-plparser tdb python-gobject libgudev
  14          grilo)
  15 makedepends=(brasero gobject-introspection vala libdmapsharing lirc libgpod
  16              libmtp zeitgeist gtk-doc yelp-tools git meson)
  17 checkdepends=(check xorg-server-xvfb)
  18 optdepends=('gst-plugins-ugly: Extra media codecs'
  19             'gst-plugins-bad: Extra media codecs'
  20             'gst-libav: Extra media codecs'
  21             'brasero: Audio CD Recorder plugin'
  22             'libdmapsharing: DAAP Music Sharing plugin'
  23             'grilo-plugins: Grilo media browser plugin'
  24             'lirc: LIRC plugin'
  25             'libgpod: Portable Players - iPod plugin'
  26             'libmtp: Portable Players - MTP plugin'
  27             'gvfs-mtp: Portable Players - Android plugin'
  28             'zeitgeist: Zeitgeist logging plugin')
  29 options=(debug)
  30 _commit=1b14819fc3937d9f03edd8dac092228cb4589240  # tags/v3.4.6^0
  31 source=("git+https://gitlab.gnome.org/GNOME/rhythmbox.git#commit=$_commit")
  32 sha512sums=('SKIP')
  33
  34 pkgver() {
  35   cd $pkgname
  36   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  37 }
  38
  39 prepare() {
  40   cd $pkgname
  41
  42   # Allow building with a newer version of meson
  43   sed -i '/unsupported version of meson/d' meson.build
  44 }
  45
  46 build() {
  47   arch-meson $pkgname build -D gtk_doc=true
  48   meson compile -C build
  49 }
  50
  51 check() (
  52   glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/$pkgname/data}"
  53   export GSETTINGS_SCHEMA_DIR GSETTINGS_BACKEND=memory CK_TIMEOUT_MULTIPLIER=3
  54
  55   xvfb-run -s '-nolisten local' \
  56     meson test -C build --print-errorlogs
  57 )
  58
  59 package() {
  60   meson install -C build --destdir "$pkgdir"
  61
  62   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  63   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  64 }