zip/trunk/PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=zip
   5 pkgver=3.0
   6 _pkgver=${pkgver/./}
   7 pkgrel=10
   8 pkgdesc='Compressor/archiver for creating and modifying zipfiles'
   9 url='http://www.info-zip.org/Zip.html'
  10 arch=('x86_64')
  11 license=('custom')
  12 depends=('bzip2')
  13 source=("https://downloads.sourceforge.net/infozip/${pkgname}${_pkgver}.tar.gz"
  14         'https://src.fedoraproject.org/rpms/zip/raw/rawhide/f/zip-3.0-currdir.patch'
  15         'https://src.fedoraproject.org/rpms/zip/raw/rawhide/f/zip-3.0-exec-shield.patch'
  16         'https://src.fedoraproject.org/rpms/zip/raw/rawhide/f/zip-3.0-format-security.patch'
  17         'https://src.fedoraproject.org/rpms/zip/raw/rawhide/f/zipnote.patch')
  18 sha256sums=('f0e8bb1f9b7eb0b01285495a2699df3a4b766784c1765a8f1aeedf63c0806369'
  19             '44cac3d4e8b447988b6e4eeb4bb6e701110cedfb09ea49eac471011328c8acab'
  20             '10f0f3756a2415e33edf1455373b322404962b743b3a52a757b669e47dd7f1b2'
  21             '3759134487afad9c63e2e9693aa05b9dcc67f55a9ef961e82074b587b094292a'
  22             '89249a3f1fdf838b795ce432a2d763fdbe913d6a146541e41b7a2e2769291ba0')
  23
  24 options=('!makeflags')
  25
  26 prepare() {
  27         cd "${srcdir}/${pkgname}${_pkgver}"
  28         sed -e "/^CFLAGS_NOOPT =/s/\$/ $CPPFLAGS $CFLAGS/" -i unix/Makefile
  29         sed -e "s/^LFLAGS1=''/LFLAGS1=$LDFLAGS/" -i unix/configure
  30         patch -p1 -i ../zip-3.0-currdir.patch
  31         patch -p1 -i ../zip-3.0-exec-shield.patch
  32         patch -p1 -i ../zip-3.0-format-security.patch
  33         patch -p1 -i ../zipnote.patch
  34 }
  35
  36 build() {
  37         cd "${srcdir}/${pkgname}${_pkgver}"
  38         make -f unix/Makefile prefix=/usr generic_gcc
  39 }
  40
  41 package() {
  42         cd "${srcdir}/${pkgname}${_pkgver}"
  43         make -f unix/Makefile prefix="${pkgdir}"/usr \
  44                 MANDIR="${pkgdir}"/usr/share/man/man1 \
  45                 install
  46         install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  47 }