devhelp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Link Dupont <link@subpop.net>
   4
   5 pkgbase=devhelp
   6 pkgname=(devhelp devhelp-docs)
   7 pkgver=41.2+r48+g14272cae
   8 pkgrel=1
   9 pkgdesc="API documentation browser for GNOME"
  10 url="https://wiki.gnome.org/Apps/Devhelp"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(webkit2gtk)
  14 makedepends=(git appstream-glib gobject-introspection meson yelp-tools
  15              gi-docgen)
  16 options=(debug)
  17 _commit=14272caec5175cacba4a044f4cacd591c0db8351  # main
  18 source=("git+https://gitlab.gnome.org/GNOME/devhelp.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd devhelp
  23   git describe --tags | sed 's/\.alpha/alpha/;s/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd devhelp
  28 }
  29
  30 build() {
  31   arch-meson devhelp build \
  32     -D gtk_doc=true \
  33     -D plugin_emacs=true \
  34     -D plugin_gedit=true \
  35     -D plugin_vim=true
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package_devhelp() {
  44   groups=(gnome-extra)
  45
  46   meson install -C build --destdir "$pkgdir"
  47
  48   # Split -docs
  49   mkdir -p docs/usr/share
  50   mv -t docs/usr/share "$pkgdir"/usr/share/doc
  51 }
  52
  53 package_devhelp-docs() {
  54   pkgdesc+=" (documentation)"
  55   depends=()
  56
  57   mv -t "$pkgdir" docs/*
  58 }