libxslt/repos/extra-x86_64/PKGBUILD

   1 # Contributor: Eric Belanger <eric@archlinux.org>
   2 # Contributor: John Proctor <jproctor@prium.net>
   3
   4 pkgname=libxslt
   5 pkgver=1.1.35
   6 pkgrel=1
   7 pkgdesc="XML stylesheet transformation library"
   8 url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis"
   9 arch=(x86_64)
  10 license=(custom)
  11 depends=(libxml2 libgcrypt)
  12 makedepends=(git python)
  13 checkdepends=(docbook-xml)
  14 optdepends=('python: Python bindings')
  15 provides=(lib{,e}xslt.so)
  16 _commit=50af4e65da712ceb59f98a7feeeab2ddc3324ab9  # tags/v1.1.35^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
  18         0001-Make-generate-id-deterministic.patch)
  19 sha256sums=('SKIP'
  20             '0b1dc7ac703e347eace1b92f7ef48735a8b6013b8e5b9620a9ca882d8bf46a74')
  21
  22 pkgver() {
  23   cd libxslt
  24   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd libxslt
  29
  30   # Make xsltproc output reproducible for packages which use it to generate documentation
  31   git apply -3 ../0001-Make-generate-id-deterministic.patch
  32
  33   NOCONFIGURE=1 ./autogen.sh
  34 }
  35
  36 build() {
  37   cd libxslt
  38   ./configure --prefix=/usr --disable-static
  39   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  40   make
  41 }
  42
  43 check() {
  44   cd libxslt
  45   make check
  46 }
  47
  48 package() {
  49   cd libxslt
  50   make DESTDIR="$pkgdir" install
  51   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  52 }
  53
  54 # vim:set sw=2 et: