accountsservice/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=accountsservice
   5 pkgver=22.08.8
   6 pkgrel=2
   7 pkgdesc="D-Bus interface for user account query and manipulation"
   8 url="https://gitlab.freedesktop.org/accountsservice/accountsservice"
   9 arch=(x86_64)
  10 license=(GPL3)
  11 depends=(glib2 polkit systemd shadow libxcrypt)
  12 makedepends=(gtk-doc gobject-introspection git meson docbook-xsl xmlto vala)
  13 checkdepends=(python-gobject python-dbusmock)
  14 options=(debug)
  15 _commit=1ef3add46983af875adfed5d29954cbfb184f688  # tags/22.08.8^0
  16 source=("git+https://gitlab.freedesktop.org/accountsservice/accountsservice.git#commit=$_commit"
  17         fix-tests.diff)
  18 sha256sums=('SKIP'
  19             '2da027faae5e477ed9ff57e3fc3cb8cd607073835118a05dd7b86bb7ff7c47fd')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26
  27 prepare() {
  28   cd $pkgname
  29
  30   # Tests are broken: https://github.com/martinpitt/python-dbusmock/issues/118
  31   git apply -3 ../fix-tests.diff
  32 }
  33
  34 build() {
  35   local meson_options=(
  36     -D admin_group=wheel
  37     -D docbook=true
  38     -D gtk_doc=true
  39   )
  40
  41   arch-meson $pkgname build "${meson_options[@]}"
  42   meson compile -C build
  43 }
  44
  45 check() {
  46   meson test -C build --print-errorlogs
  47 }
  48
  49 package() {
  50   depends+=(libg{lib,object,io}-2.0.so libsystemd.so libcrypt.so)
  51   provides+=(libaccountsservice.so)
  52
  53   meson install -C build --destdir "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 et: