libplist/trunk/PKGBUILD

   1 # Maintainer : Tom Gundersen <teg@jklm.no>
   2 # Maintainer : Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Gabriel Martinez < reitaka at gmail dot com >
   4
   5 pkgname=libplist
   6 pkgver=2.2.0
   7 pkgrel=5
   8 pkgdesc="A library to handle Apple Property List format whereas it's binary or XML"
   9 url="https://libimobiledevice.org/"
  10 arch=('x86_64')
  11 license=('GPL2' 'LGPL2.1')
  12 depends=('glib2')
  13 makedepends=('python' 'cython' 'autoconf-archive' 'git' 'python-setuptools')
  14 options=('!makeflags')
  15 _commit=c5a30e9267068436a75b5d00fcbf95cb9c1f4dcd
  16 source=("git+https://github.com/libimobiledevice/libplist#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   # Update ac_python_devel.m4 to newer ax_python_devel.m4
  27   git cherry-pick -n 42bb64ba96
  28   NOCONFIGURE=1 ./autogen.sh
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 check() {
  39   cd $pkgname
  40   make check
  41 }
  42
  43 package() {
  44   cd $pkgname
  45   make DESTDIR="$pkgdir" install
  46   install -D -m644 cython/plist.pxd "${pkgdir}"/usr/include/plist/cython/plist.pxd
  47 }