faust/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2
   3 pkgname=faust
   4 pkgver=0.9.46
   5 pkgrel=1
   6 pkgdesc="A compiled language for real-time audio signal processing."
   7 arch=('i686' 'x86_64')
   8 url="http://faust.grame.fr/"
   9 license=('GPL')
  10 depends=('ruby')
  11 conflicts=('faust-cvs' 'faust-git' 'faust2-git')
  12 source=("http://downloads.sourceforge.net/project/faudiostream/$pkgname-$pkgver.tar.gz")
  13 md5sums=('fe76d8a5905547d62817631fda5d4204')
  14
  15 build() {
  16   cd "$srcdir/$pkgname-$pkgver"
  17
  18   make PREFIX=/usr
  19 }
  20
  21 package() {
  22   cd "$srcdir/$pkgname-$pkgver"
  23
  24   make PREFIX=/usr DESTDIR="$pkgdir/" install
  25
  26   # docs
  27   install -d "$pkgdir/usr/share/doc/$pkgname"
  28   install -Dm644 documentation/*.{pdf,txt} \
  29     "$pkgdir/usr/share/doc/$pkgname"
  30
  31   # fix paths in faust utils
  32   sed -i 's|/local||' "$pkgdir/usr/bin/faust2"*
  33
  34   ## syntax highlighting files
  35   cd syntax-highlighting
  36
  37   # kate
  38   install -Dm644 $pkgname.xml \
  39     "$pkgdir/usr/share/apps/katepart/syntax/$pkgname.xml"
  40
  41   # gedit
  42   install -Dm644 $pkgname.lang \
  43     "$pkgdir/usr/share/gtksourceview-2.0/language-specs/$pkgname.lang"
  44   install -Dm644 $pkgname.lang \
  45     "$pkgdir/usr/share/gtksourceview-3.0/language-specs/$pkgname.lang"
  46
  47   # highlight
  48   install -Dm644 dsp.lang \
  49     "$pkgdir/usr/share/highlight/langDefs/dsp.lang"
  50
  51   # vim
  52   install -Dm644 $pkgname.vim \
  53     "$pkgdir/usr/share/vim/vimfiles/syntax/$pkgname.vim"
  54 }