wings3d/PKGBUILD

   1
   2 # Maintainer: kappa <kappacurve@gmail.com>
   3 pkgname=wings3d
   4 _pkgname=wings
   5 pkgver=1.4.1
   6 pkgrel=4
   7 pkgdesc="3D modeling program."
   8 arch=('i686' 'x86_64')
   9 url="http://www.wings3d.com"
  10 license=('GPL')
  11 depends=('esdl>=1.0.1')
  12 optdepends=('povray: rendering support via POV-Ray' 'kerkythea: rendering support via Kerkythea')
  13 replaces=('wings' 'wings-devel')
  14 install=wings3d.install
  15 source=(http://downloads.sourceforge.net/wings/${_pkgname}-${pkgver}.tar.bz2
  16         wings3d wings3d.desktop wings3d.png wings3d.install)
  17 md5sums=('f62a06acdbf2d4ef09ce2bf55e8cec0f'
  18          '62fd2b01d06b88b64d6ea4f043c6cc48'
  19          'bd136dc7a2ebea6293b188c928fe4c78'
  20          '150ee5b1b9b44e20862210c9b01e53f4'
  21          'fe97a01e5f683b08eb8079120117d94e')
  22 build() {
  23   cd "${srcdir}/${_pkgname}-${pkgver}"
  24
  25   export ESDL_PATH=$(echo /usr/lib/erlang/lib/esdl-*)
  26   make
  27   make lang
  28 }
  29
  30 package() {
  31   cd "${srcdir}/${_pkgname}-${pkgver}"
  32
  33   mkdir -p ${pkgdir}/usr/lib/${pkgname}
  34   for subdir in ebin fonts patches plugins shaders textures ; do
  35     cp -r "${srcdir}/${_pkgname}-${pkgver}/${subdir}/" "${pkgdir}/usr/lib/${pkgname}"
  36   done
  37
  38   install -D -m 755 ${srcdir}/wings3d ${pkgdir}/usr/bin/wings3d
  39   install -D -m 644 ${srcdir}/wings3d.desktop ${pkgdir}/usr/share/applications/wings3d.desktop
  40   install -D -m 644 ${srcdir}/wings3d.png ${pkgdir}/usr/share/pixmaps/wings3d.png
  41   install -D -m 644 ${srcdir}/${_pkgname}-${pkgver}/license.terms ${pkgdir}/usr/share/licenses/wings3d/license.terms
  42 }
  43
  44
  45