gnurobbo/PKGBUILD

   1 # Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>
   2 # Maintainer:  Jesse Jaara      <jesse.jaara@gmail.com>
   3
   4 pkgname=gnurobbo
   5 pkgver=0.66
   6 pkgrel=1
   7 pkgdesc='A free port of QXLands logic game "Robbo" for the Atari XE/XL'
   8 arch=('i686' 'x86_64')
   9 url="http://$pkgname.sourceforge.net/"
  10 license=('GPL')
  11 depends=('sdl_ttf' 'sdl_mixer' 'sdl_image')
  12 optdepends=('gnurobbo-data-nonfree')
  13 source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver-source.tar.gz \
  14         dummy.dat \
  15         $pkgname.desktop)
  16
  17 build() {
  18   cd ${srcdir}/${pkgname}-${pkgver}
  19
  20   sed     -e 's|#MUSIC=-DHAVE_MUSIC|MUSIC=-DHAVE_MUSIC|g' \
  21   -e 's|=-O3 -pipe -Wall -fomit-frame-pointer|+=|g' \
  22         -i Makefile
  23
  24   sed '/#define DEBUG_DUMP_VM_USAGE/d' -i game.c
  25
  26   # remove non-free data
  27   sed 's|original.dat|dummy.dat|g' -i levels.h
  28
  29   make PACKAGE_DATA_DIR=/usr/share/${pkgname}
  30
  31 }
  32
  33 package() {
  34   cd ${srcdir}/${pkgname}-${pkgver}
  35
  36   make PACKAGE_DATA_DIR=${pkgdir}/usr/share/${pkgname} BINDIR=${pkgdir}/usr/bin DOCDIR=${pkgdir}/usr/share/doc/${pkgname} install
  37
  38   mkdir ${pkgdir}/usr/share/gnurobbo/music
  39   rm -r ${pkgdir}/usr/share/gnurobbo/{levels/original.dat,skins/original}
  40
  41   install -m644 ChangeLog COPYING README ${pkgdir}/usr/share/doc/${pkgname}/
  42   install -Dm644 icon32.png ${pkgdir}/usr/share/pixmaps/${pkgname}.png
  43
  44   install -Dm644 ../dummy.dat ${pkgdir}/usr/share/${pkgname}/levels/dummy.dat
  45   install -Dm644 ../${pkgname}.desktop ${pkgdir}/usr/share/applications/${pkgname}.desktop
  46 }
  47
  48 # vim:set ts=2 sw=2 et:
  49 md5sums=('77fdf9a186a08c1f95b94bd35ebbc21c'
  50          '904dd16b523e97c867d9a31aeacef1b6'
  51          'e520a3c136854383627d1d960a41f8b2')