msmtp-nomta/PKGBUILD

   1 #
   2 # Maintainer: Clemens Buchacher <drizzd@aon.at>
   3 #
   4 # This is a copy of the msmtp package from [extra], except for the
   5 # removed provides=('smtp-forwarder'), in order to allow
   6 # simultaneous use msmtp with an MTA such as for example postfix.
   7 #
   8
   9 pkgname=msmtp-nomta
  10 pkgver=1.4.25
  11 pkgrel=1
  12 pkgdesc="A mini smtp client (without smtp-forwarder conflict)"
  13 arch=('i686' 'x86_64')
  14 license=('GPL3')
  15 url="http://msmtp.sourceforge.net"
  16 depends=('gnutls' 'libidn')
  17 makedepends=('texlive-core')
  18 conflicts=('msmtp')
  19 install=msmtp.install
  20 source=(http://download.sourceforge.net/sourceforge/msmtp/msmtp-${pkgver}.tar.bz2)
  21 md5sums=('2d9603a7b5c1ebd83ea289ac2aa3a634')
  22
  23 build() {
  24   cd "${srcdir}/msmtp-${pkgver}"
  25   ./configure --prefix=/usr --sysconfdir=/etc --with-ssl=gnutls
  26   make
  27   make -C doc html pdf
  28 }
  29
  30 package() {
  31   cd "${srcdir}/msmtp-${pkgver}"
  32   make DESTDIR="${pkgdir}" install
  33   make DESTDIR="${pkgdir}" -C doc install-html install-pdf
  34
  35 # Installing example configs and scripts to /usr/share/doc/msmtp
  36 # as they are not installed by default (Debian and Gentoo do it this way)
  37   install -d "${pkgdir}/usr/share/doc/msmtp"
  38   cp -r scripts/{find_alias,msmtp-gnome-tool,msmtpqueue,msmtpq,set_sendmail} "${pkgdir}/usr/share/doc/msmtp/"
  39   install -D -m644 doc/*.example "${pkgdir}/usr/share/doc/msmtp/"
  40
  41   install -D -m644 scripts/vim/msmtp.vim "${pkgdir}/usr/share/vim/vimfiles/syntax/msmtp.vim"
  42 }