quanta-git/PKGBUILD

   1 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   2 # Contributor: mosra <mosra@centrum.cz>
   3
   4 pkgname=quanta-git
   5 pkgver=20110604
   6 pkgrel=1
   7 pkgdesc="An IDE for Web Development based on the KDevelop Platform"
   8 arch=('i686' 'x86_64')
   9 url="http://quanta.kdewebdev.org/"
  10 license=('GPL')
  11 depends=('kdevplatform-git')
  12 optdepends=('qjson' 'kdevelop-pg-qt-git')
  13 makedepends=('cmake' 'automoc4' 'git' 'flex')
  14 provides=('quanta')
  15 replaces=('quanta')
  16 conflicts=('quanta')
  17 source=()
  18 md5sums=()
  19
  20 _gitroot="git://anongit.kde.org/quanta"
  21 _gitname="quanta"
  22
  23 build() {
  24     cd "${srcdir}"
  25
  26     msg "Connecting to the GIT server...."
  27
  28     if [ -d $_gitname ] ; then
  29         cd $_gitname
  30
  31         # Change remote url to anongit
  32         if [ -z "$(git remote -v | grep anongit)" ] ; then
  33             git remote set-url origin ${_gitroot}
  34         fi
  35
  36         git pull origin
  37         msg "The local files are updated."
  38     else
  39         git clone $_gitroot $_gitname
  40     fi
  41
  42     msg "GIT checkout done"
  43     msg "Starting make..."
  44
  45     mkdir -p "${srcdir}/build"
  46     cd "${srcdir}/build"
  47
  48     cmake ../${_gitname} \
  49         -DCMAKE_INSTALL_PREFIX=/usr \
  50         -DCMAKE_BUILD_TYPE=RELEASE
  51
  52     make
  53 }
  54
  55 package() {
  56     cd "${srcdir}/build"
  57
  58     make DESTDIR="${pkgdir}" install
  59 }