banshee-youtube-unstable/PKGBUILD

   1 pkgname=banshee-youtube-unstable
   2 _realname=banshee
   3 pkgver=1.9.6
   4 pkgrel=2
   5 pkgdesc="Music management and playback for GNOME with Youtube extension enabled"
   6 arch=('i686' 'x86_64')
   7 url="http://banshee-project.org/"
   8 license=('MIT')
   9 depends=('sqlite3' 'ndesk-dbus-glib' 'mono-addins' 'taglib-sharp'
  10          'gstreamer0.10-good-plugins' 'gstreamer0.10-base-plugins'
  11          'gnome-sharp' 'libmtp' 'ipod-sharp' 'boo' 'mono-zeroconf'
  12          'libxxf86vm' 'gnome-doc-utils' 'gnome-icon-theme' 'desktop-file-utils' 'webkit-sharp' 'gdata-sharp' 'libgpod')
  13 makedepends=('pkgconfig' 'intltool')
  14 optdepends=('gstreamer0.10-ugly-plugins: Extra media codecs'
  15             'gstreamer0.10-bad-plugins: Extra media codecs'
  16             'gstreamer0.10-ffmpeg: Extra media codecs'
  17             'brasero: CD burning'
  18             'notify-sharp-svn: Display Banshee tray icon')
  19 options=('!libtool' '!makeflags' '!emptydirs')
  20 provides=('banshee')
  21 conflicts=('banshee')
  22 install=banshee.install
  23 source=(http://download.banshee-project.org/${_realname}/unstable/${pkgver}/${_realname}-${pkgver}.tar.bz2)
  24
  25 md5sums=('97b41c2110a3d0b220a9f45e45e25675')
  26
  27 build() {
  28   export MONO_SHARED_DIR="${srcdir}/.wabi"
  29   mkdir -p "${MONO_SHARED_DIR}"
  30   cd "${srcdir}/${_realname}-${pkgver}"
  31   ./configure --prefix=/usr \
  32               --sysconfdir=/etc \
  33               --localstatedir=/var \
  34               --disable-docs \
  35               --disable-static || return 1
  36   make || return 1
  37 }
  38
  39 package() {
  40   export MONO_SHARED_DIR="${srcdir}/.wabi"
  41   mkdir -p "${MONO_SHARED_DIR}"
  42   cd "${srcdir}/${_realname}-${pkgver}"
  43   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1
  44
  45   install -m755 -d "${pkgdir}/usr/share/licenses/${_realname}"
  46   install -m644 COPYING "${pkgdir}/usr/share/licenses/${_realname}/" || return 1
  47
  48   install -d -m755 "${pkgdir}/usr/share/gconf/schemas"
  49   gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${_realname}.schemas" --domain banshee-1 ${pkgdir}/etc/gconf/schemas/*.schemas || return 1
  50   rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
  51   #rm $pkgdir/usr/share/applications/mimeinfo.cache
  52 }
  53