czui/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2
   3 _name=cZUI
   4 pkgname=czui
   5 pkgver=0.4.0
   6 pkgrel=1
   7 pkgdesc="A C++ user interface toolkit for rapid development of zoomable interfaces."
   8 arch=(i686 x86_64)
   9 url="http://czui.sourceforge.net/"
  10 license=('GPL')
  11 depends=('sdl')
  12 makedepends=('doxygen')
  13 options=('!libtool')
  14 source=("http://downloads.sourceforge.net/project/$pkgname/$pkgname/$_name-$pkgver/$_name-$pkgver.tar.bz2")
  15 md5sums=('4b1983a8e71b67daa3390bc99e0d0b0b')
  16
  17 build() {
  18   cd "$srcdir/$_name-$pkgver"
  19
  20   # add missing header
  21   sed -i '25a#include <cstddef>' src/include/cZUI/context.h
  22   sed -i '14a#include <cstddef>' src/include/cZUI/alloc_list.h
  23
  24   # doc path fix
  25   sed -i '/cZUI/s/$(prefix)/$(DESTDIR)\/$(datarootdir)/' doxygen/Makefile.*
  26
  27   # dot fix
  28   sed -i '/dot/s/\/usr\/bin\///' Doxyfile.in
  29
  30   ./configure --prefix=/usr \
  31               --enable-static=no
  32   make
  33
  34   # generate html docs
  35   doxygen
  36 }
  37
  38 package() {
  39   cd "$srcdir/$_name-$pkgver"
  40   make DESTDIR="$pkgdir/" install
  41 }
  42
  43 # vim:set ts=2 sw=2 et: