conduit/PKGBUILD

   1 # Maintainer: György Balló <ballogy@freestart.hu>
   2 pkgname=conduit
   3 pkgver=0.3.17
   4 pkgrel=8
   5 pkgdesc="Synchronization for GNOME"
   6 arch=('any')
   7 url="http://live.gnome.org/Conduit"
   8 license=('GPL')
   9 depends=('dbus-python>=0.80.0' 'pygoocanvas>=0.9.0' 'gstreamer0.10-python' 'python2-gconf' 'python-pysqlite' 'python-vobject' 'pywebkitgtk' 'hicolor-icon-theme' 'xdg-utils')
  10 makedepends=('intltool>=0.35.0' 'gnome-doc-utils>=0.3.2')
  11 optdepends=('python-gdata: required for Google module'
  12             'python2-feedparser: required for Feed module'
  13             'python2-flickrapi: required for Flickr module'
  14             'libgpod: required for iPod module'
  15             'python-evolution: required for Evolution module'
  16             'python-imaging: required for Facebook module'
  17             'python-simplejson: required for Facebook module')
  18 install=$pkgname.install
  19 source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  20 sha256sums=(dfbc00490b0170f22eb6e73b893da40c48556d8982b8400484e19fa617f5f934)
  21
  22 build() {
  23   cd "$srcdir/$pkgname-$pkgver"
  24   find . -type f | xargs sed -i 's@^#!.*python$@#!/usr/bin/python2@'
  25
  26   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  27               --disable-scrollkeeper \
  28               PYTHON=python2
  29   make
  30 }
  31
  32 package() {
  33   cd "$srcdir/$pkgname-$pkgver"
  34
  35   make DESTDIR="$pkgdir/" install
  36 }