nini/PKGBUILD

   1 # Maintainer: György Balló <ballogy@freestart.hu>
   2 # Contributor: MutantMonkey <mutantmonkey@gmail.com>
   3 # Contributor: Madek <gonzaloseguel@gmail.com>
   4
   5 pkgname=nini
   6 _pkgname=Nini
   7 pkgver=1.1.0
   8 pkgrel=3
   9 pkgdesc="An uncommonly powerful .NET configuration library designed to help build highly configurable applications quickly"
  10 arch=('any')
  11 url="http://nini.sourceforge.net/"
  12 license=('MIT')
  13 depends=('mono')
  14 makedepends=('unzip')
  15 source=(http://downloads.sourceforge.net/$pkgname/$_pkgname-$pkgver.zip
  16         $pkgname-1.1.pc)
  17 md5sums=('63384f75fabd401cff1500f738d452f4'
  18          '6e2cabea421a72247d4f1cdf1ffac9b6')
  19
  20 build() {
  21   cd "$srcdir/$_pkgname"
  22
  23   sn -k $_pkgname.snk
  24   gmcs -t:library -out:Bin/$_pkgname.dll -keyfile:$_pkgname.snk \
  25        -r:System,System.Data,System.Xml \
  26        Source/{AssemblyInfo,Config/*,/Ini/*,/Util/*}.cs
  27 }
  28
  29 package() {
  30   cd "$srcdir/$_pkgname"
  31
  32   gacutil -i Bin/$_pkgname.dll -package $_pkgname -root $pkgdir/usr/lib/
  33   install -Dm644 $srcdir/$pkgname-1.1.pc $pkgdir/usr/lib/pkgconfig/$pkgname-1.1.pc
  34   install -Dm644 LICENSE.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE.txt
  35 }