yafaray/PKGBUILD

   1 # Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
   2 pkgname=yafaray
   3 pkgver=0.1.1
   4 pkgrel=2
   5 pkgdesc="Raytracing open source render engine"
   6 arch=('i686' 'x86_64')
   7 url="http://www.yafaray.org/"
   8 license=('LGPL2')
   9 depends=('openexr' 'libxml2')
  10 optdepends=('qt: QT GUI' 'python2: Blender exporter')
  11 makedepends=('scons' 'swig' 'qt')
  12 conflicts=('yafaray-svn')
  13 source=(http://static.yafaray.org/sources/YafaRay.$pkgver.zip \
  14         http://static.yafaray.org/sources/YafaRay-blender.$pkgver.zip)
  15 md5sums=('d1722dec25299f6f3fcc1d7c661a4e90'
  16          'd7e7f86b9e90e7f960707ebaea1843ab')
  17
  18 build() {
  19   cd "$srcdir/$pkgname"
  20
  21   msg "Writing user-config.py"
  22   echo "PREFIX = '"$pkgdir"/usr'" > user-config.py
  23   echo "REL_CCFLAGS = '$CFLAGS -ffast-math'" >> user-config.py
  24   echo "WITH_YF_QT = 'true'" >> user-config.py
  25   echo "YF_QTDIR = '/usr'" >> user-config.py
  26
  27   sed -i 's|$YF_PLUGINPATH|/usr/lib/yafaray|' tools/writeconfig.py
  28
  29   scons
  30   scons swig
  31 }
  32
  33 package() {
  34   cd "$srcdir/$pkgname"
  35   scons install
  36
  37   # install python bindings and blender export scripts
  38   install -d -m755 "$pkgdir"/usr/share/blender/scripts
  39   install -m644 bindings/python/* "$pkgdir"/usr/share/blender/scripts
  40   install -m644 "$srcdir"/yafaray-blender/*.py "$pkgdir"/usr/share/blender/scripts
  41 }
  42
  43 # vim:set ts=2 sw=2 et: