appmenu-gtk/PKGBUILD

   1 # Maintainer: György Balló <ballogy@freestart.hu>
   2 pkgbase=appmenu-gtk
   3 pkgname=appmenu-gtk
   4 true && pkgname=(appmenu-gtk2 appmenu-gtk3)
   5 pkgver=0.3.0
   6 pkgrel=2
   7 arch=(i686 x86_64)
   8 url="https://launchpad.net/appmenu-gtk"
   9 license=(LGPL)
  10 makedepends=('gtk2-ubuntu>=2.18' 'gtk3-ubuntu>=3.0' 'libdbusmenu-gtk2>=0.3.101' 'libdbusmenu-gtk3>=0.3.101')
  11 options=(!libtool)
  12 source=(http://launchpad.net/appmenu-gtk/0.3/0.3.0/+download/$pkgbase-$pkgver.tar.gz)
  13 md5sums=('2379672a7d00fa1ef5b15c67f76886be')
  14
  15 build() {
  16   cd "$srcdir/$pkgbase-$pkgver"
  17
  18   [[ -d build-gtk2 ]] || mkdir build-gtk2
  19   pushd build-gtk2
  20   ../configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  21               --disable-static --with-gtk2
  22   make
  23   popd
  24
  25   [[ -d build-gtk3 ]] || mkdir build-gtk3
  26   pushd build-gtk3
  27   ../configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  28               --disable-static
  29   make
  30   popd
  31 }
  32
  33 package_appmenu-gtk2() {
  34   pkgdesc="Adds appmenu support for GTK+ 2 apps"
  35   depends=('gtk2-ubuntu>=2.18' 'libdbusmenu-gtk2>=0.3.101')
  36
  37   cd "$srcdir/$pkgbase-$pkgver/build-gtk2"
  38
  39   make DESTDIR="$pkgdir/" install
  40   install -Dm755 80appmenu "$pkgdir/etc/profile.d/80appmenu.sh"
  41   rm -r "$pkgdir/etc/X11"
  42 }
  43
  44 package_appmenu-gtk3() {
  45   pkgdesc="Adds appmenu support for GTK+ 3 apps"
  46   depends=('gtk3-ubuntu>=3.0' 'libdbusmenu-gtk3>=0.3.101')
  47
  48   cd "$srcdir/$pkgbase-$pkgver/build-gtk3"
  49
  50   make DESTDIR="$pkgdir/" install
  51   install -Dm755 80appmenu-gtk3 "$pkgdir/etc/profile.d/80appmenu-gtk3.sh"
  52   rm -r "$pkgdir/etc/X11"
  53 }
  54
  55 pkgdesc="Adds appmenu support for GTK+ apps"
  56 depends=('gtk2-ubuntu>=2.18' 'gtk3-ubuntu>=3.0' 'libdbusmenu>=0.3.101')
  57 true && depends=()