coccinella/PKGBUILD

   1 # Maintainer: SpepS <dreamspepser at yahoo dot it>
   2
   3 pkgname=coccinella
   4 pkgver=0.96.20
   5 pkgrel=1
   6 pkgdesc="A free and open-source cross-platform communication tool based on jabber with a built-in whiteboard for improved collaboration with other people."
   7 arch=(any)
   8 url="http://thecoccinella.org/"
   9 license=('GPL')
  10 depends=('tkpng' 'tktreectrl')
  11 optdepends=('snack: sound support')
  12 conflicts=('coccinella-bin')
  13 install="$pkgname.install"
  14 source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/Coccinella-${pkgver}Src.tar.gz"
  15         "$pkgname.desktop")
  16 md5sums=('7d4fd6fb492f99e785b208aedb1d1e3e'
  17          '3368bf4dbcec9ff12031c52d3898ca4c')
  18
  19 build() {
  20   cd "${srcdir}/Coccinella-${pkgver}Src"
  21
  22   # Remove unneded stuff
  23   rm -rf bin
  24
  25   # Permission fixes
  26   find . -type d -exec chmod 755 {} \;
  27   chmod 755 Coccinella.tcl
  28 }
  29
  30 package() {
  31   cd "${srcdir}/Coccinella-${pkgver}Src"
  32
  33   # Bin
  34   install -d "$pkgdir/usr/"{bin,share/$pkgname}
  35   ln -s "/usr/share/$pkgname/Coccinella.tcl" "$pkgdir/usr/bin/coccinella"
  36
  37   # Data
  38   cp -a `find . -mindepth 1 -maxdepth 1 -type d` Coccinella.tcl "$pkgdir/usr/share/$pkgname"
  39
  40   # Desktop file and pixmaps
  41   install -Dm 644 ../$pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
  42   install -Dm 644 themes/Oxygen/icons/128x128/coccinella2.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
  43 }
  44
  45 # vim:set ts=2 sw=2 et: