gnome-terminal-gtk2/PKGBUILD

   1 # $Id: PKGBUILD 121328 2011-04-30 15:31:28Z ibiru $
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-terminal-gtk2
   5 tarname=gnome-terminal
   6 pkgver=3.0.1
   7 pkgrel=2
   8 pkgdesc="The GNOME Terminal Emulator (using GTK2)"
   9 arch=('i686' 'x86_64')
  10 license=('GPL')
  11 depends=('gconf' 'vte' 'gsettings-desktop-schemas' 'libsm')
  12 makedepends=('gnome-doc-utils' 'gtk2' 'intltool')
  13 #gtk2 is needed for gtk-builder-convert
  14 #https://bugzilla.gnome.org/show_bug.cgi?id=588945
  15 #https://bugzilla.gnome.org/show_bug.cgi?id=588732
  16 options=('!emptydirs')
  17 conflicts=('gnome-terminal')
  18 provides=('gnome-terminal')
  19 url="http://www.gnome.org"
  20 groups=('gnome')
  21 install=gnome-terminal.install
  22 source=(http://ftp.gnome.org/pub/gnome/sources/${tarname}/3.0/${tarname}-${pkgver}.tar.bz2
  23         exitcode.patch)
  24 sha256sums=('388eda40663566cb785e2d92180e0b584c2c89acc3e7bcd30605601710fddc48'
  25             '263030e9905329d8e651421b575a80c37e30733373378896c94d2c6d6e0ee056')
  26
  27 build() {
  28   cd "${srcdir}/${tarname}-${pkgver}"
  29   patch -Np1 -i "${srcdir}/exitcode.patch"
  30   ./configure --prefix=/usr --sysconfdir=/etc \
  31       --localstatedir=/var --disable-scrollkeeper \
  32       --with-gtk=2.0
  33   make
  34 }
  35
  36 package() {
  37   cd "${srcdir}/${tarname}-${pkgver}"
  38   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
  39
  40   install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  41   gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${tarname}.schemas" --domain gnome-terminal ${pkgdir}/etc/gconf/schemas/*.schemas
  42   rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
  43 }