stlport/PKGBUILD

   1 # Maintainer: Jonathan Liu <net147@gmail.com>
   2 pkgname=stlport
   3 _realpkgname=STLport
   4 pkgver=5.2.1
   5 pkgrel=1
   6 pkgdesc="An implementation of the C++ Standard Library"
   7 arch=('i686' 'x86_64')
   8 url="http://www.stlport.org/"
   9 license=('custom')
  10 depends=('gcc-libs')
  11 source=("http://downloads.sourceforge.net/project/${pkgname}/${_realpkgname}/${_realpkgname}-${pkgver}/${_realpkgname}-${pkgver}.tar.gz"
  12         "LICENSE")
  13 md5sums=('b20ace9f4a487b2614dfbb205bee112c'
  14          '3a759c6b31d076057bea2a78d5f53748')
  15
  16 build() {
  17   cd "${srcdir}/${_realpkgname}-${pkgver}"
  18   unset CFLAGS
  19   unset CXXFLAGS
  20   unset LDFLAGS
  21   sed -i -e 's#/usr/bin/install#/bin/install#' build/Makefiles/gmake/linux/sys.mak
  22   ./configure --prefix="${pkgdir}/usr"
  23   make
  24 }
  25
  26 check() {
  27   cd "${srcdir}/${_realpkgname}-${pkgver}"
  28   make -k check
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${_realpkgname}-${pkgver}"
  33   install -d -m755 "${pkgdir}/usr/include"
  34   install -d -m755 "${pkgdir}/usr/lib"
  35   make install
  36   install -D -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  37 }
  38
  39 # vim:set ts=2 sw=2 et: