arduino-syslibs/PKGBUILD

   1 # Maintainer: PyroPeter <googlemail.com@abi1789>
   2
   3 pkgname=arduino-syslibs
   4 pkgver=0022
   5 pkgrel=1
   6 pkgdesc="Arduino SDK (depends on external avrdude and librxtx)"
   7 arch=('any')
   8 url="http://arduino.cc/en/Main/Software"
   9 license=('GPL')
  10 depends=('avr-libc' 'java-runtime' 'sh' 'xdg-utils' 'avrdude' rxtx)
  11 provides=('arduino')
  12 conflicts=('arduino')
  13 source=("http://arduino.googlecode.com/files/arduino-$pkgver.tgz"
  14         'arduino'
  15         'arduino-syslibs.install'
  16         'avrdude'
  17         'arduino.png'
  18         'arduino.desktop')
  19 md5sums=('2429c118381a4a761d7f5717183ac387' 'e2c80b367bfbd96e56e656c198516288' 'bec2d12f581b2a8904abad00e7653492' 'c4cff287b732fd09d71bb81db3dcb167' '9e36d33891d5e68d38ec55d1494499a5' 'eebc4d6495864bea99ad057af801afb9')
  20
  21 package() {
  22   cd "$srcdir/arduino-$pkgver"
  23   mkdir -p "$pkgdir"/usr/{bin,share/{doc,applications}}
  24
  25   # remove architecture dependend stuff
  26   rm hardware/tools/avrdude
  27   rm lib/librxtxSerial.so
  28
  29   # copy the whole SDK to /usr/share/arduino/
  30   cp -r . "$pkgdir/usr/share/arduino"
  31
  32   # install a wrapper for avrdude
  33   install -m755 "$srcdir/avrdude" "$pkgdir/usr/share/arduino/hardware/tools/"
  34
  35   # at least support the FHS a little bit:
  36   install -m755 "$srcdir/arduino" "$pkgdir/usr/bin/arduino"
  37   ln -s /usr/share/arduino/reference "$pkgdir/usr/share/doc/arduino"
  38
  39   # desktop icon
  40   install -m644 "$srcdir/arduino.desktop" "$pkgdir/usr/share/applications/"
  41   install -m644 "$srcdir/arduino.png" "$pkgdir/usr/share/arduino/"
  42 }