allacrost-svn/PKGBUILD

   1 # Contributor: Yaohan Chen <yaohan.chen@gmail.com>
   2 # Contributor: Jakob Gruber <jakob.gruber@gmail.com>
   3 # Contributor: Christoph Zeiler <rabyte*gmail>
   4
   5 pkgname=allacrost-svn
   6 pkgver=1969
   7 pkgrel=1
   8 pkgdesc='A single player 2D role-playing game inspired by classic console RPGs'
   9 arch=('i686' 'x86_64')
  10 url='http://www.allacrost.org/'
  11 license=('GPL2')
  12 depends=('libgl' 'mesa' 'qt' 'openal' 'libvorbis' 'sdl_net' 'sdl_ttf' 'luabind')
  13 makedepends=('boost' 'subversion')
  14 conflicts=('allacrost')
  15 options=('!emptydirs')
  16 _svntrunk=https://allacrost.svn.sourceforge.net/svnroot/allacrost/trunk/game
  17 _svnmod=allacrost
  18
  19 build() {
  20   cd "$srcdir"
  21
  22   if [ -d $_svnmod/.svn ]; then
  23     (cd $_svnmod && svn up -r $pkgver)
  24   else
  25     svn co $_svntrunk --config-dir ./ -r $pkgver $_svnmod
  26   fi
  27
  28   msg "SVN checkout done or server timeout"
  29   msg "Starting make..."
  30
  31   rm -rf "$srcdir/$_svnmod-build"
  32   cp -r "$srcdir/$_svnmod" "$srcdir/$_svnmod-build"
  33   cd "$srcdir/$_svnmod-build"
  34
  35   #
  36   # Build
  37   #
  38   autoreconf -i
  39   ./configure --prefix=/usr
  40
  41   sed -i 's|bindir = ${prefix}/games|bindir = ${prefix}/bin|' Makefile
  42   sed -i 's|datarootdir = ${prefix}/share/games|datarootdir = ${prefix}/share|' Makefile
  43   make
  44 }
  45
  46 package() {
  47   cd "$srcdir/$_svnmod-build"
  48   make DESTDIR="${pkgdir}" install
  49 }