hon/PKGBUILD

   1 # Contributor:  Slash           <yahoo.com: demodevil5>
   2 # Maintainer:   Jesse Jaara     <gmail.com: jesse.jaara>
   3
   4 #### To speed up package creation.
   5 #### If you are planning to distribute
   6 #### This on some custon repo, you might
   7 #### want to use the defaut slow but
   8 #### much better xz compression.
   9 PKGEXT=.pkg.tar.gz
  10
  11 pkgname=hon
  12 pkgver=2.5.0
  13 pkgrel=2
  14 pkgdesc="Heroes of Newerth is a Real Time Strategy game heavily influcenced by DotA"
  15 arch=('i686' 'x86_64')
  16 url="http://www.heroesofnewerth.com/"
  17 license=('custom:HoN')
  18 depends=('libgl' 'libxml2' 'mesa' 'speex' 'curl' 'freetype2')
  19 makedepends=('unzip')
  20 options=(!strip)
  21 install=hon.install
  22 source=('hon.desktop' 'license' "http://dl.heroesofnewerth.com/HoNClient-${pkgver}.sh")
  23
  24 package() {
  25     ## Thx to messo8080 for reminding uss about the /tmp dir
  26     ## On new installs this dir is in ram by default ^^.
  27
  28     if `pwd | grep -q "/tmp"`; then
  29         echo \
  30 "You are trying to build this pkg in /tmp dir.
  31 This is not so good idea as /tmp dir is in ram
  32 by default. If you know that you have lots of
  33 ram (>4G) and swap and want to continue building in
  34 the current directory write yes and press ENTER.
  35 Otherwice write no and press ENTER.
  36 Continue?"
  37         read answer
  38                 if [ "${answer}" == "no" ]; then
  39                         false
  40                 fi
  41     fi
  42
  43     # Create Destination Directory
  44     mkdir -p "${pkgdir}/opt/"
  45     mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
  46
  47     # Extract Files
  48     sh -c "unzip ${srcdir}/HoNClient-${pkgver}.sh data/* -d \"${pkgdir}/opt/\"; true"
  49     mv "${pkgdir}"/opt/{data,hon}
  50
  51     # Install License
  52     cp "${srcdir}/license" "${pkgdir}/usr/share/licenses/${pkgname}/"
  53
  54     # Install Desktop Shortcut
  55     install -D -m 0644 "${srcdir}/hon.desktop" \
  56         "${pkgdir}/usr/share/applications/hon.desktop"
  57
  58     # Install Client Launcher
  59     mkdir -p "${pkgdir}/usr/bin"
  60     ln -s /opt/hon/hon.sh "${pkgdir}/usr/bin/hon"
  61
  62     ## Remove un-needed libs
  63     ## fmodex and linpng aren't compitable with Arch
  64     ## freetype causes segfault on some systems O_o
  65     system_libs="libcurl.so.4  libgcc_s.so.1  libspeexdsp.so.1  libspeex.so.1  libstdc++.so.6"
  66     if [ "${CARCH}" == 'x86_64' ]; then
  67         ## remove 32bit's
  68         rm -r "${pkgdir}"/opt/hon/*-x86{,.so}
  69         cd "${pkgdir}/opt/hon/libs-x86_64" && rm ${system_libs}
  70     else
  71         ## remove 64bit's
  72         rm -r "${pkgdir}"/opt/hon/*-x86_64{,.so}
  73         cd "${pkgdir}/opt/hon/libs-x86" && rm ${system_libs}
  74     fi
  75
  76     # Set Ownership to root:games
  77     chown -R root:games "${pkgdir}/opt/hon"
  78     chmod -R g+w "${pkgdir}/opt/hon"
  79 }
  80
  81 md5sums=('d3fa56f17b5eb21d4da01e8d628fbc97'
  82          'c00baef7ab9f20a5c9cc398e4bf512dd'
  83          '2e23853d956fcba7d7402aab202bdbf8')